blob: 73fac665c712317f7a3c4d5ffbb1b6a7396f4fe7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id$
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=alsa-utils
pkgver=1.0.29
pkgrel=1
pkgdesc="An alternative implementation of Linux sound support"
arch=('i686' 'x86_64')
url="http://www.alsa-project.org"
#can not use >=$pkgver due to use of letters in alsa-lib update versioning
depends=("alsa-lib>1.0.24" 'pciutils' 'ncurses' 'psmisc' 'libsamplerate')
makedepends=('xmlto' 'docbook-xsl')
license=('GPL')
source=(ftp://ftp.alsa-project.org/pub/utils/$pkgname-${pkgver}.tar.bz2
90alsa)
build() {
cd ${srcdir}/${pkgname}-${pkgver}
./configure --prefix=/usr --disable-alsaconf --sbindir=/usr/bin \
--with-udev-rules-dir=/usr/lib/udev/rules.d \
--with-systemdsystemunitdir=/usr/lib/systemd/system
make
# fix udev rules genaration
cd alsactl
make 90-alsa-restore.rules
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
install -D -m755 ../90alsa ${pkgdir}/etc/pm/sleep.d/90alsa
# install alsa udev rule file
install -D -m644 alsactl/90-alsa-restore.rules \
${pkgdir}/usr/lib/udev/rules.d/90-alsa-restore.rules
# dir where to save ALSA state
install -d ${pkgdir}/var/lib/alsa
}
md5sums=('6b289bf874c4c9a63f4b3973093dd404'
'529216f6a46e61a546640e08ea7a0879')
|
