blob: 8eee4befa3de377be2d72d4605db287d820f2beb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 187052 2013-06-03 11:16:15Z allan $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
pkgname=cdrkit
pkgver=1.1.11
pkgrel=3
pkgdesc="Suite of programs for CD/DVD recording, ISO image creation, and audio CD extraction"
arch=('i686' 'x86_64')
url="http://cdrkit.org/"
license=('GPL2')
depends=('file' 'bzip2')
optdepends=('perl: for dirsplit')
makedepends=('cmake')
source=(http://cdrkit.org/releases/$pkgname-$pkgver.tar.gz)
prepare() {
cd "$srcdir/$pkgname-$pkgver"
sed -i "s#sbin#bin#" netscsid/CMakeLists.txt
}
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make PREFIX="$pkgdir/usr" install
# Make symlinks for cdrtools compatibility
cd "$pkgdir/usr/bin"
ln -s wodim cdrecord
ln -s readom readcd
ln -s genisoimage mkisofs
ln -s genisoimage mkhybrid
ln -s icedax cdda2wav
cd "$pkgdir/usr/share/man/man1"
ln -s wodim.1 cdrecord.1
ln -s readom.1 readcd.1
ln -s genisoimage.1 mkisofs.1
ln -s genisoimage.1 mkhybrid.1
ln -s icedax.1 cdda2wav.1
}
md5sums=('efe08e2f3ca478486037b053acd512e9')
|
