blob: ed80d2080531c9ea8838a06aef3feecfa6c83a5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id$
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Jochem Kossen <j.kossen@home.nl>
pkgname=fakeroot
pkgver=1.22
pkgrel=1
pkgdesc='Tool for simulating superuser privileges'
arch=(x86_64)
license=(GPL)
url='http://packages.debian.org/fakeroot'
groups=(base-devel)
install=fakeroot.install
depends=(glibc filesystem sed util-linux sh)
#makedepends=(po4a)
checkdepends=(sharutils)
source=(http://ftp.debian.org/debian/pool/main/f/$pkgname/${pkgname}_${pkgver}.orig.tar.bz2
silence-dlerror.patch)
md5sums=('fae64c9aeb2c895ead8e1b99bf50c631'
'5fba0b541b5af39d804265223fda525c')
prepare() {
cd $pkgname-$pkgver
patch -p1 -i "$srcdir"/silence-dlerror.patch
./bootstrap
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--libdir=/usr/lib/libfakeroot \
--disable-static \
--with-ipc=sysv
make
# cd doc
# po4a -k 0 --rm-backups --variable 'srcdir=../doc/' po4a/po4a.cfg
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -dm755 "$pkgdir/etc/ld.so.conf.d/"
echo '/usr/lib/libfakeroot' > "$pkgdir/etc/ld.so.conf.d/fakeroot.conf"
# install README for sysv/tcp usage
install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
}
|
