blob: 251ac74ca9cad8e8826596d938675a6ddb50b9cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=freetype2
pkgname=('freetype2' 'freetype2-demos' 'freetype2-docs')
pkgver=2.9
pkgrel=2
pkgdesc="Font rasterization library"
arch=(x86_64)
license=('GPL')
url="https://www.freetype.org/"
# adding harfbuzz for improved OpenType features auto-hinting
# introduces a cycle dep to harfbuzz depending on freetype wanted by upstream
depends=('zlib' 'bzip2' 'sh' 'libpng' 'harfbuzz')
makedepends=('libx11')
source=(https://download-mirror.savannah.gnu.org/releases/freetype/freetype-${pkgver}.tar.bz2{,.sig}
https://download-mirror.savannah.gnu.org/releases/freetype/freetype-doc-${pkgver}.tar.bz2{,.sig}
https://download-mirror.savannah.gnu.org/releases/freetype/ft2demos-${pkgver}.tar.bz2{,.sig}
0001-Enable-table-validation-modules.patch
0002-Enable-infinality-subpixel-hinting.patch
0003-Enable-long-PCF-family-names.patch
0001-psaux-Correctly-handle-Flex-features-52846.patch
0005-freetype-2.5.2-more-demos.patch
freetype2.sh)
sha1sums=('94c4399b1a55c5892812e732843fcb4a7c2fe657'
'SKIP'
'63e171aa5b2c46e7bece3ae7781015380d012e1f'
'SKIP'
'bd8a5d17274f987284e6f934722fb7715d00892e'
'SKIP'
'b69531770c343d403be294b7e4d25ac45738c833'
'3d26a569f0cb94c28a550577f5dcaadb4e193d91'
'770f1981734a837bcf065564c91644b4cc5e256a'
'21ad7dd31e16adb5b39adfa5671018a736626562'
'72cfecbe738085eec475e012617661ad0cc9b76f'
'bc6df1661c4c33e20f5ce30c2da8ad3c2083665f')
validpgpkeys=('58E0C111E39F5408C5D3EC76C1A60EACE707FDA5')
prepare() {
# Rename source dir to allow building the demos
mv freetype-${pkgver} freetype2
mv ft2demos-${pkgver} freetype2-demos
cd freetype2
patch -Np1 -i ../0001-Enable-table-validation-modules.patch
patch -Np1 -i ../0002-Enable-infinality-subpixel-hinting.patch
patch -Np1 -i ../0003-Enable-long-PCF-family-names.patch
# Freetype 2.9 regression: bad rendering for some Type 1 fonts
# https://savannah.nongnu.org/bugs/?52846
patch -Np1 -i ../0001-psaux-Correctly-handle-Flex-features-52846.patch
cd ../freetype2-demos
# enable more demos
patch -Np1 -i ../0005-freetype-2.5.2-more-demos.patch
# Suppress RPATH
sed -i '/X11_LIB:%=-R%/d' graph/x11/rules.mk
}
build() {
cd freetype2
./configure --prefix=/usr --disable-static
make
# Build demos
cd ../freetype2-demos
make
}
check() {
cd freetype2
make -k check
}
package_freetype2() {
provides=('libfreetype.so')
install=freetype2.install
backup=('etc/profile.d/freetype2.sh')
cd freetype2
make DESTDIR="${pkgdir}" install
install -Dt "${pkgdir}/etc/profile.d" -m644 ../freetype2.sh
}
package_freetype2-demos() {
pkgdesc="Freetype tools and demos"
depends=('freetype2' 'libx11')
cd freetype2-demos
install -d "${pkgdir}/usr/bin"
for _i in bin/{f,t}t*; do
libtool --mode=install install $_i "${pkgdir}/usr/bin"
done
}
package_freetype2-docs() {
pkgdesc="Freetype documentation"
depends=('freetype2')
cd freetype2
install -d "${pkgdir}/usr/share/doc"
cp -a docs "${pkgdir}/usr/share/doc/freetype2"
}
# vim:set ts=2 sw=2 et:
|