blob: 5919e90813c4345a80c3647e2a1b7134ea193c1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 96353 2010-10-19 21:56:12Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gtk2
pkgver=2.22.0
pkgrel=7
pkgdesc="The GTK+ Toolkit (v2)"
arch=('i686' 'x86_64')
url="http://www.gtk.org/"
install=gtk2.install
depends=('atk>=1.30.0' 'pango>=1.28.0' 'libxcursor' 'libxinerama' 'libxrandr>=1.3.0' 'libxi>=1.3' 'libxcomposite' 'libxdamage' 'heimdal>=1.3.2' 'gnutls>=2.8.6' 'shared-mime-info' 'cairo>=1.10.0' 'gdk-pixbuf2>=2.21.7')
makedepends=('pkgconfig' 'gtk-doc' 'gobject-introspection')
replaces=('gail')
conflicts=('gtkprint-cups' 'gail')
provides=('gail=1.22.3')
options=('!libtool' '!docs')
backup=(etc/gtk-2.0/gtkrc)
license=('LGPL')
source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/2.22/gtk+-${pkgver}.tar.bz2
xid-collision-debug.patch old-icon-symlinks.patch)
sha256sums=('d9522c80d4b8a954f7474e32bd5a99ba3051996f1c4681426db5f79a1c1b4602'
'd758bb93e59df15a4ea7732cf984d1c3c19dff67c94b957575efea132b8fe558'
'1298e4103f71d0304378f1e7503011150f6f68398ae8ebae5522a48feaea7c0d')
build() {
cd "${srcdir}/gtk+-${pkgver}"
patch -Np1 -i "${srcdir}/xid-collision-debug.patch"
patch -Np1 -i "${srcdir}/old-icon-symlinks.patch"
CXX=/bin/false ./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-xinput=yes
make || return 1
}
package() {
cd "${srcdir}/gtk+-${pkgver}"
make DESTDIR="${pkgdir}" install
sed -i "s#env python#env python2#" $pkgdir/usr/bin/gtk-builder-convert
echo 'gtk-fallback-icon-theme = "gnome"' > "${pkgdir}/etc/gtk-2.0/gtkrc"
}
|
