blob: 07302197cc04182587538ea6746612254fdabea7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 196792 2013-10-19 09:14:49Z pierre $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
pkgname=logrotate
pkgver=3.8.7
pkgrel=1
pkgdesc="Rotates system logs automatically"
arch=('i686' 'x86_64')
url="https://fedorahosted.org/logrotate/"
license=('GPL')
groups=('base')
depends=('popt' 'gzip' 'acl')
optdepends=('cron: scheduled log rotation')
backup=('etc/logrotate.conf')
source=("https://fedorahosted.org/releases/l/o/logrotate/logrotate-${pkgver}.tar.gz"
'paths.patch'
'logrotate.conf'
'logrotate.cron.daily')
build() {
cd "$srcdir/${pkgname}-${pkgver}"
patch -p0 -i "$srcdir/paths.patch"
make WITH_ACL=yes RPM_OPT_FLAGS="$CFLAGS" EXTRA_LDFLAGS="$LDFLAGS"
}
check() {
cd "$srcdir/${pkgname}-${pkgver}"
make test
}
package() {
cd "$srcdir/${pkgname}-${pkgver}"
make PREFIX="$pkgdir" MANDIR="/usr/share/man" install
mv ${pkgdir}/usr/sbin ${pkgdir}/usr/bin
install -dm755 "$pkgdir/etc/logrotate.d"
install -Dm644 "$srcdir/logrotate.conf" "$pkgdir/etc/logrotate.conf"
install -Dm744 "$srcdir/logrotate.cron.daily" "$pkgdir/etc/cron.daily/logrotate"
}
md5sums=('99e08503ef24c3e2e3ff74cc5f3be213'
'e76526bcd6fc33c9d921e1cb1eff1ffb'
'86209d257c8b8bc0ae34d6f6ef057c0f'
'dd5fd26724274fd9c827eadad60ff4c5')
|
