blob: 4d95801bb75586777cd5c68f6d914d2b2bf6e55e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
pkgbase=mplayer
pkgname=('mplayer' 'mencoder')
pkgver=37857
pkgrel=2
arch=('i686' 'x86_64')
makedepends=(
'libxxf86dga' 'libmad' 'libxinerama'
'libmng' 'libxss' 'smbclient' 'aalib' 'libcaca'
'faac' 'faad2' 'lirc' 'libxvmc' 'enca' 'libdca' 'a52dec' 'libvpx' 'unzip' 'mesa'
'live-media' 'yasm' 'git' 'mpg123' 'ladspa'
'libcdio-paranoia' 'subversion' 'x264' 'libx264' 'rtmpdump'
'libdvdcss' 'libdvdread' 'libdvdnav' 'ffmpeg'
)
license=('GPL')
url='http://www.mplayerhq.hu/'
options=('!buildflags' '!emptydirs')
source=($pkgbase-$pkgver::svn://svn.mplayerhq.hu/mplayer/trunk#revision=$pkgver
mplayer.desktop
include-samba-4.0.patch
revert-icl-fixes.patch)
md5sums=('SKIP'
'62f44a58f072b2b1a3c3d3e4976d64b3'
'868a92bdef148df7f38bfa992b26ce9d'
'3579402002b7302fdf2d146639333efd')
prepare() {
cd $pkgbase-$pkgver
# mv ../ffmpeg-*/ ./ffmpeg
patch -Np1 -i ../include-samba-4.0.patch
patch -Np0 -i ../revert-icl-fixes.patch
./version.sh
}
build() {
cd $pkgbase-$pkgver
./configure --prefix=/usr \
--enable-runtime-cpudetection \
--disable-gui \
--disable-arts \
--disable-liblzo \
--disable-speex \
--disable-openal \
--disable-libdv \
--disable-musepack \
--disable-esd \
--disable-mga \
--disable-ass-internal \
--disable-cdparanoia \
--disable-ffmpeg_a \
--enable-xvmc \
--enable-radio \
--enable-radio-capture \
--enable-smb \
--language=all \
--confdir=/etc/mplayer
[[ "$CARCH" = "i686" ]] && sed 's|-march=i486|-march=i686|g' -i config.mak
make
}
package_mplayer() {
pkgdesc='Media player for Linux'
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
depends=(
'desktop-file-utils' 'ttf-font' 'enca' 'libxss' 'a52dec' 'libvpx'
'lirc' 'libx264' 'libmng' 'libdca' 'aalib' 'libxinerama' 'smbclient'
'libmad' 'libcaca' 'libxxf86dga' 'faac' 'faad2' 'libxvmc' 'mpg123'
'libcdio-paranoia' 'rtmpdump' 'libdvdnav' 'ffmpeg'
)
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir" install-mplayer install-mplayer-man
install -Dm644 etc/{codecs.conf,input.conf,example.conf} \
"$pkgdir/etc/mplayer/"
# desktop file (FS#14770)
install -Dm644 ../mplayer.desktop \
"$pkgdir"/usr/share/applications/mplayer.desktop
install -Dm644 etc/mplayer256x256.png \
"$pkgdir"/usr/share/pixmaps/mplayer.png
}
package_mencoder() {
pkgdesc='Free command line video decoding, encoding and filtering tool'
depends=(
'enca' 'a52dec' 'libvpx' 'libx264' 'libmng' 'libdca' 'smbclient' 'libmad' 'faac' 'faad2'
'mpg123' 'libcdio-paranoia' 'rtmpdump' 'libdvdnav' 'ffmpeg'
)
make -C $pkgbase-$pkgver DESTDIR="$pkgdir" install-mencoder install-mencoder-man
find "$pkgdir"/usr/share/man -name mplayer.1 -exec rename mplayer.1 mencoder.1 {} +
}
|
