blob: 53eae4430786c58cfe37c009dbbcd2c25c210c7a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Christian Hesse <mail@eworm.de>
pkgname=openvpn
pkgver=2.4.7
pkgrel=1
pkgdesc='An easy-to-use, robust and highly configurable VPN (Virtual Private Network)'
arch=('x86_64')
url='https://openvpn.net/index.php/open-source.html'
depends=('openssl' 'lzo' 'iproute2' 'systemd' 'pkcs11-helper')
optdepends=('easy-rsa: easy CA and certificate handling'
'pam: authenticate via PAM')
makedepends=('git' 'systemd')
license=('custom')
validpgpkeys=('F554A3687412CFFEBDEFE0A312F5F7B42F2B01E7' # OpenVPN - Security Mailing List <security@openvpn.net>
'B62E6A2B4E56570B7BDC6BE01D829EFECA562812') # Gert Doering <gert@v6.de>
source=("git+https://github.com/OpenVPN/openvpn.git#tag=v${pkgver}")
#source=("git+https://github.com/OpenVPN/openvpn.git#tag=v${pkgver}?signed")
sha256sums=('SKIP')
prepare() {
cd "${srcdir}"/${pkgname}
autoreconf -i
}
build() {
mkdir "${srcdir}"/build
cd "${srcdir}"/build
"${srcdir}"/${pkgname}/configure \
--prefix=/usr \
--sbindir=/usr/bin \
--enable-iproute2 \
--enable-pkcs11 \
--enable-plugins \
--enable-systemd \
--enable-x509-alt-username
make
}
check() {
cd "${srcdir}"/build
make check
}
package() {
cd "${srcdir}"/build
# Install openvpn
make DESTDIR="${pkgdir}" install
# Create empty configuration directories
install -d -m0750 -g 90 "${pkgdir}"/etc/openvpn/{client,server}
# Install license
install -d -m0755 "${pkgdir}"/usr/share/licenses/openvpn/
ln -sf /usr/share/doc/openvpn/{COPYING,COPYRIGHT.GPL} "${pkgdir}"/usr/share/licenses/openvpn/
cd "${srcdir}"/${pkgname}
# Install examples
install -d -m0755 "${pkgdir}"/usr/share/openvpn
cp -r sample/sample-config-files "${pkgdir}"/usr/share/openvpn/examples
# Install contrib
for FILE in $(find contrib -type f); do
case "$(file --brief --mime-type "${FILE}")" in
"text/x-shellscript") install -D -m0755 "${FILE}" "${pkgdir}/usr/share/openvpn/${FILE}" ;;
*) install -D -m0644 "${FILE}" "${pkgdir}/usr/share/openvpn/${FILE}" ;;
esac
done
}
|
