blob: 6826749703728e82dc08728995f3c0e371bd32ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id$
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Igor Scabini <furester @ gmail.com>
pkgname=(cython cython2)
pkgbase=cython
pkgver=0.27.3
pkgrel=3
pkgdesc="C-Extensions for Python"
arch=(x86_64)
url="http://cython.org"
license=(APACHE)
makedepends=(python-setuptools python2-setuptools)
source=($pkgbase-$pkgver.tar.gz::"https://github.com/cython/cython/archive/$pkgver.tar.gz")
sha256sums=('648feb8a257574a3e4ef854475e7d767732ef26e870d2f9fcc1ca5b244b3ac89')
prepare() {
cp -r cython-$pkgver cython2-$pkgver
find cython2-$pkgver -name '*.py' | xargs sed -e 's|/usr/bin/env python|/usr/bin/env python2|' -e 's|/usr/bin/python|/usr/bin/python2|' -i
}
build() {
cd cython-$pkgver
python setup.py build
cd ../cython2-$pkgver
python2 setup.py build
}
package_cython() {
depends=(python python-setuptools)
cd cython-$pkgver
python setup.py install --root="$pkgdir" --skip-build
for f in cygdb cython cythonize; do
mv "$pkgdir"/usr/bin/$f "$pkgdir"/usr/bin/${f}3
ln -s ${f}3 "$pkgdir"/usr/bin/$f
done
}
package_cython2() {
depends=(python2 python2-setuptools)
cd cython2-$pkgver
python2 setup.py install --root="$pkgdir" --skip-build
for f in cygdb cython cythonize; do
mv "$pkgdir"/usr/bin/$f "$pkgdir"/usr/bin/${f}2
done
}
|
