blob: 5ed3781af6909598f7ecefb1cc4ae122ad846879 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
pkgbase=python-beautifulsoup4
pkgname=('python-beautifulsoup4' 'python2-beautifulsoup4')
pkgver=4.6.0
pkgrel=2
pkgdesc="A Python HTML/XML parser designed for quick turnaround projects like screen-scraping"
arch=('any')
url="http://www.crummy.com/software/BeautifulSoup/index.html"
license=('PSF')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest' 'python2-pytest')
source=("http://www.crummy.com/software/BeautifulSoup/bs4/download/${pkgver%.*}/${pkgbase#*-}-$pkgver.tar.gz")
sha512sums=('1a7eee4218e58cc3852e71fe4f0892f673bb46a851941264766a38eff8ef05d612d88b4641fcb478ce8f66ac50dc987ca039923c4bbb11867c74813289f7e578')
prepare() {
cp -a beautifulsoup4-$pkgver{,-py2}
}
build() {
cd "$srcdir"/beautifulsoup4-$pkgver
python setup.py build
cd "$srcdir"/beautifulsoup4-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/beautifulsoup4-$pkgver/build
py.test
cd "$srcdir"/beautifulsoup4-$pkgver-py2/build
py.test2
}
package_python-beautifulsoup4() {
depends=('python')
optdepends=('python-chardet: to autodetect character encodings'
'python-lxml: alternative HTML parser'
'python-html5lib: alternative HTML parser')
cd beautifulsoup4-$pkgver
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}
package_python2-beautifulsoup4() {
depends=('python2')
optdepends=('python2-chardet: to autodetect character encodings'
'python2-lxml: alternative HTML parser'
'python2-html5lib: alternative HTML parser')
cd beautifulsoup4-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
}
|
