blob: 1a0ab63566ec2be668828b3377f50b2012966b68 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Limao Luo <luolimao+AUR@gmail.com>
pkgbase=python-pbr
pkgname=(python-pbr python2-pbr)
pkgver=3.1.1
pkgrel=1
pkgdesc="Python Build Reasonableness"
arch=('any')
url='https://pypi.python.org/pypi/pbr'
license=('Apache')
makedepends=('python2-setuptools' 'python-setuptools' 'git')
checkdepends=('python-testscenarios' 'python2-testscenarios' 'python-testrepository' 'python2-testrepository'
'python-testresources' 'python2-testresources' 'python-mock' 'python2-mock' 'python-virtualenv'
'python2-virtualenv' 'python-wheel' 'python2-wheel' 'python-sphinx' 'python2-sphinx')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/openstack-dev/pbr/archive/$pkgver.tar.gz")
sha512sums=('c96079408f7ec0ac2e84f94e0cec5b1e6f2ca80460556cbef11568ad8a0f4bf760d5c3451fea408cd6e12acf136254d2769726310911d2e6871cea4bebdb4670')
prepare() {
cp -a pbr-$pkgver{,-py2}
find pbr-$pkgver-py2 -name \*.py -exec sed -i '1s/python$/&2/' {} +
export PBR_VERSION=$pkgver
}
build() {
cd "$srcdir"/pbr-$pkgver
python setup.py build
cd "$srcdir"/pbr-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/pbr-$pkgver
python setup.py testr || warning "Tests failed"
cd "$srcdir"/pbr-$pkgver-py2
PYTHON=python2 python2 setup.py testr || warning "Tests failed"
}
package_python-pbr() {
depends=('python-setuptools')
cd pbr-$pkgver
python setup.py install -O1 --root="$pkgdir"
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-pbr() {
depends=('python2-setuptools')
cd pbr-$pkgver-py2
python2 setup.py install -O1 --root="$pkgdir"
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
mv "$pkgdir"/usr/bin/pbr{,2}
}
|
