blob: ad443c65dd993bbceefd3183ae158ff22befa6d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id$
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: minder
pkgbase=python-pillow
pkgname=(python-pillow python2-pillow)
pkgver=5.0.0
pkgrel=1
_appname=Pillow
_py2basever=2.7
_py3basever=3.6m
pkgdesc="Python Imaging Library (PIL) fork. Python3 version."
arch=('x86_64')
url="https://python-pillow.github.io/"
license=('BSD')
depends=('lcms2' 'libtiff' 'openjpeg2')
optdepends=('freetype2: for the ImageFont module'
'libraqm: for complex text scripts'
'libwebp: for webp images'
'tk: for the ImageTK module')
makedepends=('python-setuptools' 'python2-setuptools' 'freetype2' 'libraqm' 'libwebp' 'tk')
checkdepends=('python-pytest' 'python2-pytest')
source=("https://files.pythonhosted.org/packages/source/P/$_appname/$_appname-$pkgver.tar.gz"
"freetype-2.9-testfailure.patch::https://github.com/python-pillow/Pillow/commit/4afed260dc8a2b926a8dccfeed45b085d67425ca.patch")
md5sums=('08094bc48aae6877c94f8db4b8ee8e52'
'04e168f81a434e76dab09456ad7930f9')
# future optional things:
# libimagequant
prepare() {
cd "$srcdir/${_appname}-$pkgver"
patch -p1 < ../freetype-2.9-testfailure.patch
}
build() {
cd "$srcdir/${_appname}-$pkgver"
python setup.py build
python2 setup.py build
}
check() {
cd "$srcdir/${_appname}-$pkgver"
export PYTHONPATH="$PWD/build/lib.linux-$CARCH-${_py3basever%m}"
python selftest.py
pytest
export PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_py2basever"
python2 selftest.py
pytest2
}
package_python-pillow() {
depends+=('python')
optdepends+=('python-olefile: OLE2 file support'
'python-pyqt4: for the ImageQt module'
'python-pyqt5: for the ImageQt module'
'python-pyside: for the ImageQt module')
cd "$srcdir/$_appname-$pkgver"
python3 setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -dm755 "$pkgdir/usr/include/python$_py3basever/"
install -m644 -t "$pkgdir/usr/include/python$_py3basever/" src/libImaging/*.h
}
package_python2-pillow() {
pkgdesc="Python Imaging Library (PIL) fork. Python2 version."
depends+=('python2')
optdepends+=('python2-olefile: OLE2 file support'
'python2-pyqt5: for the ImageQt module'
'python2-pyqt4: for the ImageQt module'
'python2-pyside: for the ImageQt module')
provides=('python-imaging' 'python2-imaging')
conflicts=('python-imaging' 'python2-imaging')
cd "$srcdir/${_appname}-$pkgver"
python2 setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -dm755 "$pkgdir/usr/include/python$_py2basever/"
install -m644 -t "$pkgdir/usr/include/python$_py2basever/" src/libImaging/*.h
}
|
