blob: a7ef90a990838682508cd8ea41bca6c7fcdf4058 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
pkgbase=python-pycurl
pkgname=('python-pycurl' 'python2-pycurl')
pkgver=7.43.0.1
pkgrel=1
arch=('x86_64')
url="http://pycurl.sourceforge.net/"
license=('LGPL' 'MIT')
makedepends=('python' 'python2' 'curl')
checkdepends=('python-bottle' 'python2-bottle' 'python-nose-show-skipped' 'python2-nose-show-skipped'
'vsftpd' 'python-flaky' 'python2-flaky' 'python-pyflakes' 'python2-pyflakes')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/pycurl/pycurl/archive/REL_${pkgver//./_}.tar.gz")
sha512sums=('304212ec704dda0f630abb67c14478098f8609c64a2ccc041e519af2237d803885a27d18aac1dd77ec7526cdc7bc1fab046f3be6c94b10a2e1ae43500d2c2ffe')
prepare() {
mv pycurl-REL_${pkgver//./_} pycurl-$pkgver
cp -a pycurl-$pkgver{,-py2}
cd "$srcdir"/pycurl-$pkgver
find . -name '*.py' -exec sed -i -e "s|#! /usr/bin/env python|#!/usr/bin/env python3|" {} +
sed -i 's/"share", "doc", PACKAGE/"share", "doc", "python-pycurl"/' setup.py
sed -e "s/nosetests/nosetests3/" -e "s/python/python3/" -i tests/run.sh
cd "$srcdir"/pycurl-$pkgver-py2
find . -name '*.py' -exec sed -i -e "s|#! /usr/bin/env python|#!/usr/bin/env python2|" {} +
sed -i 's/"share", "doc", PACKAGE/"share", "doc", "python2-pycurl"/' setup.py
sed -e "s/nosetests/nosetests2/" -e "s/python/python2/" -i tests/run.sh
sed -e "s/pyflakes/pyflakes-python2/" -i Makefile
}
build() {
cd "$srcdir"/pycurl-$pkgver
make
python3 setup.py build --with-ssl
cd "$srcdir"/pycurl-$pkgver-py2
make
python2 setup.py build --with-ssl
}
check() {
export PYCURL_VSFTPD_PATH=vsftpd
# We don't have HTTP2 enabled
cd "$srcdir"/pycurl-$pkgver
PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.6:$PYTHONPATH" make test || warning "Tests failed"
cd "$srcdir"/pycurl-$pkgver-py2
PYTHONPATH="$PWD/build/lib.linux-$CARCH-2.7:$PYTHONPATH" make PYTHON=python2 NOSETESTS=nosetests2 test || warning "Tests failed"
}
package_python-pycurl() {
pkgdesc="A Python 3.x interface to libcurl"
depends=('python' 'curl')
cd pycurl-$pkgver
python setup.py install -O1 --root="$pkgdir"
install -D -m644 COPYING-MIT "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-pycurl() {
pkgdesc="A Python 2.x interface to libcurl"
depends=('python2' 'curl')
cd pycurl-$pkgver-py2
python2 setup.py install -O1 --root="$pkgdir"
install -D -m644 COPYING-MIT "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|
