blob: ac5f91b078ddf479770a5efa55170ebd659ce412 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: eolianoe <eolianoe At GoogleMAIL DoT com>
pkgbase=python-requests-toolbelt
pkgname=('python-requests-toolbelt' 'python2-requests-toolbelt')
pkgver=0.9.1
pkgrel=1
pkgdesc="A toolbelt of useful classes and functions to be used with python-requests."
arch=('any')
url="https://github.com/requests/toolbelt"
license=('Apache')
makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests')
checkdepends=('python-pytest' 'python2-pytest' 'python-betamax' 'python2-betamax'
'python-mock' 'python2-mock' 'python-pyopenssl' 'python2-pyopenssl')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/requests/toolbelt/archive/$pkgver.tar.gz")
sha512sums=('12667056c225ce0bc88a5959660103feed23810890abd3890ef15581aa64c09c0552c3974473e1742cbe6200bd37d6475ad34ec051e83d4fbf0a33f320dbc0cc')
prepare() {
cp -a toolbelt-$pkgver{,-py2}
}
build() {
cd "$srcdir"/toolbelt-$pkgver
python setup.py build
cd "$srcdir"/toolbelt-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/toolbelt-$pkgver
py.test
cd "$srcdir"/toolbelt-$pkgver-py2
py.test2
}
package_python-requests-toolbelt() {
depends=('python-requests')
cd toolbelt-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
}
package_python2-requests-toolbelt() {
depends=('python2-requests')
cd toolbelt-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
}
|
