blob: d4d0da6ed27afb2388eb2ed82a3ab508d101e1e6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Hugo Osvaldo Barrera <hugo@barrera.io>
pkgbase=python-setuptools-scm
pkgname=(python-setuptools-scm python2-setuptools-scm)
pkgver=1.17.0
pkgrel=1
pkgdesc="Handles managing your python package versions in scm metadata."
arch=('any')
url="https://github.com/pypa/setuptools_scm"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest' 'python2-pytest' 'mercurial' 'git' 'python-pip' 'python2-pip')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/pypa/setuptools_scm/archive/v$pkgver.tar.gz")
sha512sums=('8846a4c0b8a901108ee3444f1682235a68d74dec6468f5f32af6502c11e9a7aedf6f81744d9fdd4d71d59b4f9ddc1e9685ca7e2084ebb247800e6d03d7e15899')
prepare() {
cp -a setuptools_scm-$pkgver{,-py2}
export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
}
build() {
cd "$srcdir"/setuptools_scm-$pkgver
python setup.py build
python setup.py egg_info
cd "$srcdir"/setuptools_scm-$pkgver-py2
python2 setup.py build
python2 setup.py egg_info
}
check() {
# Hack entry points by installing it
cd "$srcdir"/setuptools_scm-$pkgver
python setup.py install --root="$PWD/tmp_install" --optimize=1
SETUPTOOLS_SCM_PRETEND_VERSION= PYTHONPATH="$PWD/tmp_install/usr/lib/python3.6/site-packages:$PYTHONPATH" py.test
cd "$srcdir"/setuptools_scm-$pkgver-py2
python2 setup.py install --root="$PWD/tmp_install" --optimize=1
SETUPTOOLS_SCM_PRETEND_VERSION= PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2
}
package_python-setuptools-scm() {
depends=('python-setuptools')
provides=('python-setuptools_scm')
conflicts=('python-setuptools_scm')
replaces=('python-setuptools_scm')
cd "$srcdir"/setuptools_scm-$pkgver
python setup.py install --root "$pkgdir"
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-setuptools-scm() {
depends=('python2-setuptools')
provides=('python2-setuptools_scm')
conflicts=('python2-setuptools_scm')
replaces=('python2-setuptools_scm')
cd "$srcdir"/setuptools_scm-$pkgver-py2
python2 setup.py install --root "$pkgdir"
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|
