blob: f7e71da5315839d7bee75d8af41adb924b72f54d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# $Id$
# Maintainer: Dan McGee <dan@archlinux.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniele Paolella <dp@mcrservice.it>
pkgname=('python-virtualenv' 'python2-virtualenv')
pkgver=15.1.0
pkgrel=3
pkgdesc="Virtual Python Environment builder"
url="https://virtualenv.pypa.io/"
arch=('any')
license=('MIT')
makedepends=('python-setuptools' 'python-sphinx' 'python2-setuptools' 'python2-sphinx')
checkdepends=('python-pytest' 'python-mock' 'python2-pytest' 'python2-mock')
replaces=('virtualenv')
conflicts=('virtualenv')
options=('!makeflags')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/pypa/virtualenv/archive/${pkgver}.tar.gz)
md5sums=('30222e271963a437e240aee4853728d2')
sha256sums=('aea627d114a3863d6374c5a3fc3cdd08907e0ac951cf93b458e5ba5998c516de')
prepare() {
cp -a virtualenv-${pkgver}{,-py2}
cd virtualenv-${pkgver}-py2
sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|" virtualenv.py
}
build() {
(cd virtualenv-${pkgver}
python setup.py build
make -C docs text man
)
(cd virtualenv-${pkgver}-py2
python2 setup.py build
make -C docs text man
)
}
check() {
(cd virtualenv-${pkgver}
py.test
)
(cd virtualenv-${pkgver}-py2
py.test2
)
}
package_python-virtualenv() {
depends=('python-setuptools')
cd virtualenv-$pkgver
python setup.py install --prefix=/usr --root="$pkgdir" --skip-build
install -Dm 644 docs/_build/text/* -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 docs/_build/man/virtualenv.1 "${pkgdir}/usr/share/man/man1/virtualenv.1"
ln -s virtualenv.1.gz "${pkgdir}/usr/share/man/man1/virtualenv3.1.gz"
# link to a version with 3 suffix as well
ln "$pkgdir/usr/bin/virtualenv" "$pkgdir/usr/bin/virtualenv3"
install -D -m644 LICENSE.txt \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_python2-virtualenv() {
depends=('python2-setuptools')
cd virtualenv-$pkgver-py2
python2 setup.py install --prefix=/usr --root="$pkgdir" --skip-build
install -Dm 644 docs/_build/text/* -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 docs/_build/man/virtualenv.1 "${pkgdir}/usr/share/man/man1/virtualenv2.1"
# move this "old" version out of the way
mv "$pkgdir/usr/bin/virtualenv" "$pkgdir/usr/bin/virtualenv2"
install -D -m644 LICENSE.txt \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
