blob: e44493da4be355c266b1642f4d8796988af89bef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Paul Mattal <paul@archlinux.org>
pkgname=x264
pkgver=142.20140311
pkgrel=1
epoch=1
pkgdesc='Library for encoding H264/AVC video streams'
arch=('i686' 'x86_64')
url='http://www.videolan.org/developers/x264.html'
license=('GPL')
depends=('glibc')
makedepends=('yasm' 'git')
source=(git://git.videolan.org/x264.git#commit=aff928d2)
md5sums=('SKIP')
pkgver() {
cd $pkgname
local _ver=$(grep '#define X264_BUILD' x264.h | cut -d' ' -f3)
local _date=$(git log -1 --format="%cd" --date=short | tr -d -)
echo ${_ver}.${_date}
}
build() {
cd $pkgname
./configure --prefix=/usr \
--enable-shared \
--enable-pic
make
}
package() {
make -C $pkgname DESTDIR="$pkgdir" install
}
|
