blob: 246166f79fbcaea6d84489eec1b3960988579e55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id$
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: kfgz <kfgz at interia pl>
pkgname=x265
pkgver=1.7
pkgrel=3
pkgdesc='Open Source H265/HEVC video encoder'
arch=('i686' 'x86_64')
url='https://bitbucket.org/multicoreware/x265'
license=('GPL')
depends=('gcc-libs')
makedepends=('yasm' 'cmake')
provides=('libx265.so')
source=($pkgname-$pkgver.tar.bz2::$url/get/$pkgver.tar.bz2
x265-1.7-fix-slowness-with-gcc-5.1.patch)
md5sums=('d6020c277b05ab44f8222342aaa9c99f'
'30c7fc491f22cbdec1ee17caab7d620a')
prepare() {
cd multicoreware-x265-*
patch -p1 -i "$srcdir"/x265-1.7-fix-slowness-with-gcc-5.1.patch
}
build() {
cd multicoreware-x265-*/build/linux
[[ $CARCH == x86_64 ]] && LDFLAGS+=',-z,noexecstack'
cmake -G "Unix Makefiles" -DCMAKE_INSTALL_PREFIX=/usr ../../source
make
}
package() {
cd multicoreware-x265-*/build/linux
make DESTDIR="$pkgdir" install
}
|
