blob: af0f0ad389303c619cd672702a8991d07029aefe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=xorg-xrdb
pkgver=1.1.0
pkgrel=2
pkgdesc="X server resource database utility"
arch=('i686' 'x86_64')
url="https://xorg.freedesktop.org/"
license=('custom')
depends=('libx11' 'libxmu')
makedepends=('xorg-util-macros')
optdepends=('gcc: for preprocessing'
'mcpp: a lightweight alternative for preprocessing')
groups=('xorg-apps' 'xorg')
source=(https://xorg.freedesktop.org/archive/individual/app/xrdb-${pkgver}.tar.bz2)
sha256sums=('73827b6bbfc9d27ca287d95a1224c306d7053cd7b8156641698d7dc541ca565b')
build() {
cd xrdb-${pkgver}
# --with-cpp=path comma-separated list of paths to cpp command for xrdb to use at runtime
# mcpp is small but can fail, FS#46934
./configure --prefix=/usr --with-cpp=/usr/bin/cpp,/usr/bin/mcpp
make
}
package() {
cd xrdb-${pkgver}
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
