blob: 575e523436fb82dd7f0cf19f299854f86dfe72c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=bash-completion
pkgver=2.4
pkgrel=1
pkgdesc="Programmable completion for the bash shell"
arch=('any')
url="https://github.com/scop/bash-completion"
license=('GPL2')
depends=('bash')
options=('!emptydirs' '!makeflags')
source=("https://github.com/scop/bash-completion/releases/download/$pkgver/$pkgname-$pkgver.tar.xz")
sha1sums=('c02fb9c0f669d178f678c291ea17ddadfd011250')
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# bash-completion is sourced in /etc/bash.bashrc so that non-bash shell don't source it
rm "${pkgdir}/etc/profile.d/bash_completion.sh"
# remove Slackware's makepkg completion
rm "${pkgdir}/usr/share/bash-completion/completions/makepkg"
# remove completions which overlap with util-linux
rm "${pkgdir}/usr/share/bash-completion/completions"/{u,}mount
}
|
