blob: 1ab869bedc06a1f5e5538f427a9a4b8c7fd9f73c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: damir <damir@archlinux.org>
pkgname=fftw
pkgver=3.3.8
pkgrel=3
pkgdesc="A library for computing the discrete Fourier transform (DFT)"
arch=('x86_64')
license=('GPL2')
url="http://www.fftw.org/"
depends=('bash' 'gcc-libs' 'glibc' 'openmpi')
makedepends=('gcc-fortran')
provides=('libfftw3q_threads.so' 'libfftw3q_omp.so' 'libfftw3q.so'
'libfftw3l_threads.so' 'libfftw3l_omp.so' 'libfftw3l_mpi.so' 'libfftw3l.so'
'libfftw3f_threads.so' 'libfftw3f_omp.so' 'libfftw3f_mpi.so' 'libfftw3f.so'
'libfftw3_threads.so' 'libfftw3_omp.so' 'libfftw3_mpi.so' 'libfftw3.so')
# makedepends=('gcc-fortran' 'ocaml' 'ocaml-num' 'ocamlbuild')
source=("http://www.fftw.org/${pkgname}-${pkgver}.tar.gz")
# source=("https://github.com/${pkgname}/fftw3/archive/${pkgname}-${pkgver}.tar.gz")
sha512sums=('ab918b742a7c7dcb56390a0a0014f517a6dff9a2e4b4591060deeb2c652bf3c6868aa74559a422a276b853289b4b701bdcbd3d4d8c08943acf29167a7be81a38')
prepare() {
# issue with ocaml-num
# mv -v "fftw3-${pkgname}-${pkgver}" "${pkgname}-${pkgver}"
# (
# cd "$pkgname-$pkgver"
# cp -v NEWS ChangeLog
# autoreconf -vfi
# )
cp -av "${pkgname}-${pkgver}" "${pkgname}-${pkgver}-double"
cp -av "${pkgname}-${pkgver}" "${pkgname}-${pkgver}-long-double"
cp -av "${pkgname}-${pkgver}" "${pkgname}-${pkgver}-quad"
}
build() {
export F77='gfortran'
# use upstream default CFLAGS while keeping our -march/-mtune
CFLAGS+=" -O3 -fomit-frame-pointer -malign-double -fstrict-aliasing -ffast-math"
# default configure call
_default_configure="./configure --prefix=/usr --enable-shared --enable-threads --enable-mpi --enable-openmp"
# configure single precision
(
cd "${pkgname}-${pkgver}"
${_default_configure} --enable-sse --enable-avx --enable-single
)
# configure double precision
(
cd "${pkgname}-${pkgver}-double"
${_default_configure} --enable-sse2 --enable-avx
)
# configure long-double precission
(
cd "${pkgname}-${pkgver}-long-double"
${_default_configure} --enable-long-double
)
# configure quad precision
(
cd "${pkgname}-${pkgver}-quad"
${_default_configure} --disable-mpi --enable-quad-precision
)
make -C "${pkgname}-${pkgver}"
make -C "${pkgname}-${pkgver}-double"
make -C "${pkgname}-${pkgver}-long-double"
make -C "${pkgname}-${pkgver}-quad"
}
package() {
make DESTDIR="${pkgdir}" install -C "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install -C "${pkgname}-${pkgver}-double"
make DESTDIR="${pkgdir}" install -C "${pkgname}-${pkgver}-long-double"
make DESTDIR="${pkgdir}" install -C "${pkgname}-${pkgver}-quad"
cd "${pkgname}-${pkgver}"
install -vDm 644 {AUTHORS,ChangeLog,NEWS,README,TODO} \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|
