blob: f0337ba2011bff8ecf73560e028049c67d8afd04 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id$
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
pkgname=gd
pkgver=2.2.5
pkgrel=1
pkgdesc="Library for the dynamic creation of images by programmers"
arch=('x86_64')
url="http://www.libgd.org/"
license=('custom')
depends=('fontconfig' 'libxpm' 'libwebp')
optdepends=('perl: bdftogd script')
checkdepends=('ttf-liberation')
source=("https://github.com/libgd/libgd/releases/download/gd-${pkgver}/libgd-${pkgver}.tar.xz")
md5sums=('8d8d6a6189513ecee6e893b1fb109bf8')
build() {
cd libgd-${pkgver}
./configure \
--prefix=/usr \
--disable-rpath
make
}
check() {
cd libgd-${pkgver}
# see https://github.com/libgd/libgd/issues/302
[[ ${CARCH} == 'i686' ]] || FREETYPE_PROPERTIES='truetype:interpreter-version=35' make check
}
package() {
cd libgd-${pkgver}
make DESTDIR="${pkgdir}" install
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
