blob: 229c36c0ee63794fed6abd9981a0b4a9c54b7a13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=gst-plugins-base
pkgname=(gst-plugins-base-libs gst-plugins-base)
pkgver=1.12.4
pkgrel=1
pkgdesc="GStreamer Multimedia Framework Base Plugins"
url="https://gstreamer.freedesktop.org/"
arch=(x86_64)
license=(LGPL)
makedepends=(gstreamer orc libxv iso-codes alsa-lib cdparanoia libvisual libvorbis libtheora pango
opus gobject-introspection autoconf-archive git pkgconfig)
checkdepends=(gtk3 qt5-base)
options=(!emptydirs)
_commit=e07c69f65598068b380753066783a1c67e3d4464 # tags/1.12.4^0
source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-base#commit=$_commit"
"gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd $pkgbase
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgbase
git submodule init
git config --local submodule.common.url "$srcdir/gst-common"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgbase
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
--with-package-name="GStreamer Base Plugins (Arch Linux)" \
--with-package-origin="https://www.archlinux.org/" \
--enable-experimental --disable-static
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
sed -e 's/^SUBDIRS_EXT =.*/SUBDIRS_EXT =/' -i Makefile
}
check() {
cd $pkgbase
make check
}
package_gst-plugins-base-libs() {
pkgdesc="GStreamer Multimedia Framework Base Plugin libraries"
depends=(gstreamer orc libxv iso-codes)
cd $pkgbase
make DESTDIR="$pkgdir" install
}
package_gst-plugins-base() {
depends=("gst-plugins-base-libs=$pkgver" alsa-lib cdparanoia libvisual libvorbis
libtheora pango opus)
cd $pkgbase
make -C gst-libs DESTDIR="$pkgdir" install
make -C ext DESTDIR="$pkgdir" install
make -C gst-libs DESTDIR="$pkgdir" uninstall
}
|
