blob: 9c7785649e67d76e53d4160a44cc061cdfddb2eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gstreamer
pkgver=1.12.4
pkgrel=1
pkgdesc="GStreamer open-source multimedia framework core library"
url="https://gstreamer.freedesktop.org/"
arch=(x86_64)
license=(LGPL)
depends=(libxml2 glib2 libunwind libcap libelf)
makedepends=(intltool pkgconfig gtk-doc gobject-introspection autoconf-archive git
valgrind bash-completion)
checkdepends=(gmp gsl gtk3)
_commit=505a24ff6843a04e4f75c5e03caa7b2774806fc3 # tags/1.12.4^0
install=gstreamer.install
source=("git+https://anongit.freedesktop.org/git/gstreamer/gstreamer#commit=$_commit"
"gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
git submodule init
git config --local submodule.common.url "$srcdir/gst-common"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
--with-package-name="GStreamer (Arch Linux)" \
--with-package-origin="https://www.archlinux.org/" \
--disable-static
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname
make check
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
