blob: eafa339701fd0b79e4e1e08836d127cc7f1d6bf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id$
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Art Gramlich <art@gramlich-net.com>
pkgname=icu
pkgver=54.1
pkgrel=1
pkgdesc="International Components for Unicode library"
arch=(i686 x86_64)
url="http://www.icu-project.org/"
license=('custom:icu')
depends=('gcc-libs>=4.7.1-5' 'sh')
#makedepends=('clang')
source=(#http://download.icu-project.org/files/${pkgname}4c/${pkgver}/${pkgname}4c-${pkgver/./_}-src.tgz
http://download.icu-project.org/files/${pkgname}4c/${pkgver}/${pkgname}4c-${pkgver//./_}-src.tgz
icu.8198.revert.icu5431.patch)
md5sums=('e844caed8f2ca24c088505b0d6271bc0'
'ebd5470fc969c75e52baf4af94a9ee82')
prepare() {
cd icu/source
# fix Malayalam encoding https://bugzilla.redhat.com/show_bug.cgi?id=654200
patch -Rp3 -i ${srcdir}/icu.8198.revert.icu5431.patch
}
build() {
cd icu/source
./configure --prefix=/usr \
--sysconfdir=/etc \
--mandir=/usr/share/man \
--sbindir=/usr/bin
make
}
check() {
cd icu/source
make -k check # passes all
}
package() {
cd icu/source
make -j1 DESTDIR=${pkgdir} install
# Install license
install -Dm644 ${srcdir}/icu/license.html ${pkgdir}/usr/share/licenses/icu/license.html
}
|
