blob: 75a12c1b001394b6365ba9bc8c6f55b7fa2994e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: [vEX] <niechift.dot.vex.at.gmail.dot.com>
# Contributor: Zeqadious <zeqadious.at.gmail.dot.com>
# Contributor: BlackIkeEagle < ike DOT devolder AT gmail DOT com >
_prefix=/usr
pkgname=xbmc
pkgver=11.0
pkgrel=9
pkgdesc="A software media player and entertainment hub for digital media"
arch=('i686' 'x86_64')
url="http://xbmc.org"
license=('GPL' 'custom')
depends=('hicolor-icon-theme' 'fribidi' 'lzo2' 'smbclient' 'libtiff' 'libva' 'libpng' 'libcdio' 'yajl' 'libmysqlclient' 'libjpeg' 'libsamplerate' 'glew' 'libssh' 'libmicrohttpd' 'libxrandr' 'sdl_mixer' 'sdl_image' 'python2' 'libass' 'libmpeg2' 'libmad' 'libmodplug' 'jasper' 'rtmpdump' 'unzip' 'mesa-demos' 'xorg-xdpyinfo' 'libbluray' 'libnfs' 'afpfs-ng' 'libshairport' 'avahi' 'bluez' 'linhes-scripts>=7-31')
makedepends=('boost' 'cmake' 'gperf' 'nasm' 'libxinerama' 'zip' 'vdpau-video' 'libcec' 'udisks' 'upower' 'bluez')
optdepends=(
'libcec: support for Pulse-Eight USB-CEC adapter'
'vdpau-video: accelerated video playback for nvidia cards'
'xvba-video: accelerated video playback for amd cards'
'lirc: remote controller support'
'udisks: automount external drives'
'upower: used to trigger suspend functionality'
'unrar: access compressed files without unpacking them'
)
install="${pkgname}.install"
source=("http://mirrors.xbmc.org/releases/source/xbmc-$pkgver.tar.gz" 'xbmc11.patch' 'xbmc.sh')
build() {
cd "${srcdir}/xbmc-$pkgver"
patch -p1 < ../xbmc11.patch
# fix lsb_release dependency
sed -i -e 's:/usr/bin/lsb_release -d:cat /etc/arch-release:' xbmc/utils/SystemInfo.cpp
# Bootstrapping XBMC
./bootstrap
# Configuring XBMC
export PYTHON_VERSION=2 # external python v2
./configure --prefix=$_prefix --exec-prefix=$_prefix \
--enable-debug \
--enable-optimizations \
--enable-gl \
--enable-sdl \
--enable-vaapi \
--enable-vdpau \
--enable-xvba \
--enable-joystick \
--enable-xrandr \
--enable-rsxs \
--enable-projectm \
--enable-x11 \
--enable-rtmp \
--enable-samba \
--enable-nfs \
--enable-afpclient \
--enable-airplay \
--enable-airtunes \
--enable-ffmpeg-libvorbis \
--enable-dvdcss \
--disable-hal \
--enable-avahi \
--enable-webserver \
--enable-optical-drive \
--enable-libbluray \
--enable-texturepacker \
--enable-udev \
--enable-libusb \
--enable-libcec \
--enable-external-libraries \
--disable-external-ffmpeg \
--disable-crystalhd
# Now (finally) build
make
}
package() {
cd "${srcdir}/xbmc-$pkgver"
# Running make install
make DESTDIR="${pkgdir}" install
# run feh with python2
sed -i -e 's/python/python2/g' ${pkgdir}${_prefix}/bin/xbmc
# lsb_release fix
sed -i -e 's/which lsb_release &> \/dev\/null/\[ -f \/etc\/arch-release ]/g' "${pkgdir}${_prefix}/bin/xbmc"
sed -i -e "s/lsb_release -a 2> \/dev\/null | sed -e 's\/\^\/ \/'/cat \/etc\/arch-release/g" "${pkgdir}${_prefix}/bin/xbmc"
# Tools
install -D -m 0755 "${srcdir}/xbmc-$pkgver/xbmc-xrandr" "${pkgdir}${_prefix}/share/xbmc/xbmc-xrandr"
install -D -m 0755 "${srcdir}/xbmc-$pkgver/tools/TexturePacker/TexturePacker" "${pkgdir}${_prefix}/share/xbmc/"
# Licenses
install -d -m 0755 "${pkgdir}${_prefix}/share/licenses/${pkgname}"
for licensef in LICENSE.GPL copying.txt; do
mv "${pkgdir}${_prefix}/share/doc/xbmc/${licensef}" "${pkgdir}${_prefix}/share/licenses/${pkgname}"
done
mkdir -p ${pkgdir}/usr/LH/bin
install -D -m 0755 ${srcdir}/xbmc.sh ${pkgdir}/usr/LH/bin
}
# vim:set ts=2 sw=2 et:
md5sums=('9e8a26ee25173c7268abea7f1d82d428'
'5aa2e21a1f9fea60a2e5bb345e5aefd0'
'e48a3d87984669ef206e902bc8290ff9')
|
