blob: 567df1df633310443dfabf4b79ccd71ccbc0a48a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
pkgname=rsyslog
pkgver=8.2212.0
pkgrel=1
pkgdesc="An enhanced multi-threaded syslogd with a focus on security and reliability"
url="http://www.rsyslog.com/"
arch=('x86_64' 'i686' 'aarch64')
license=('GPL3')
depends=('libestr' 'liblogging' 'librelp' 'libfastjson')
makedepends=('postgresql-libs>=8.4.1' 'libmariadbclient' 'net-snmp' 'gnutls'
'python-docutils' 'libestr' 'liblogging' 'librelp' 'libfastjson' 'bison' 'flex')
optdepends=('postgresql-libs: PostgreSQL Database Support'
'libmariadbclient: MySQL Database Support'
'net-snmp'
'gnutls')
backup=('etc/rsyslog.conf'
'etc/logrotate.d/rsyslog')
options=('strip' 'zipman')
source=("$pkgname-$pkgver.tar.gz::https://github.com/rsyslog/rsyslog/archive/v${pkgver}.tar.gz"
'rsyslog.logrotate'
'rsyslog.conf'
'rsyslog.service')
sha256sums=('4b5f2205e91adf5e5821de8957a42b937505607f663c71ee381aca0011ea8e42'
'0f5bea3fd4dff2c9f097bf95768b2e1f6e9cfd9a08eab98bc3b3b4d2ed44119a'
'0a28fcc346cd47e8142cdbb5df7503277f624b59a9ec783adb1581d65e92b041'
'81b9f9b78395405b679849143a6709911d00e9317928fdb2a2540f52965847c2')
install=$pkgname.install
build() {
cd "$srcdir"/${pkgname}-${pkgver}
./autogen.sh --prefix=/usr \
--sbindir=/usr/bin \
--enable-mysql \
--enable-pgsql \
--enable-mail \
--enable-imfile \
--enable-snmp \
--enable-gnutls \
--enable-inet \
--enable-imjournal \
--enable-omjournal \
--enable-relp \
--enable-impstats \
--enable-imptcp \
--enable-omprog \
--with-systemdsystemunitdir=/usr/lib/systemd/system
make
}
package() {
cd "$srcdir"/${pkgname}-${pkgver}
make install DESTDIR="$pkgdir"
install -D -m644 "$srcdir"/${pkgname}.conf "$pkgdir"/etc/${pkgname}.conf
install -D -m644 "$srcdir"/${pkgname}.logrotate "$pkgdir"/etc/logrotate.d/${pkgname}
install -D -m644 "$srcdir"/${pkgname}.service "$pkgdir"/usr/lib/systemd/system/${pkgname}.service
}
|
