blob: f09969d9060b2ae9ce28c91bccd7bd568cd2fde0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: asamk <asamk@gmx.de>
pkgname=signal-cli
pkgver=0.11.10
pkgrel=1
pkgdesc="Provides a commandline and dbus interface for secure Signal messaging."
arch=('any')
url="https://github.com/AsamK/signal-cli"
license=('GPL3')
depends=('java-runtime-headless>=17' 'java-commons-logging' 'sh' 'libsignal-client')
makedepends=('java-environment>=17' 'gradle' 'asciidoc')
source=("https://github.com/AsamK/${pkgname}/archive/v${pkgver}.tar.gz"
"https://github.com/AsamK/${pkgname}/releases/download/v${pkgver}/v${pkgver}.tar.gz.asc"
"${pkgname}.sh")
sha512sums=('22542636eb5d50301dbca0442bc41ad2aa5c675f3ca7658be9818269aabe4d53819c18350d18d1cf938f7a8cce2dd6194632ee98a74a3ce95d7b325a8cdf5fe3'
'SKIP'
'f58d7851c53eae1874692f032a489cb6fb459763a4195afaf93ddd4c65939e1e4e2bbf50438e04800aded466266c3a2a37fcc0f5168f61b8e711fcf03e8e8d12')
validpgpkeys=('FA10826A74907F9EC6BBB7FC2BA2CD21B5B09570')
build() {
cd "${srcdir}"
cd "${pkgname}-${pkgver}"
GRADLE_USER_HOME="${srcdir}/.gradle" gradle --no-daemon installDist
cd man
make
}
package() {
install -m755 -d "${pkgdir}/usr/share/java/${pkgname}" \
"${pkgdir}/usr/bin" \
"${pkgdir}/usr/lib/systemd/system/" \
"${pkgdir}/usr/lib/sysusers.d/" \
"${pkgdir}/usr/lib/tmpfiles.d/" \
"${pkgdir}/usr/share/man/man1/" \
"${pkgdir}/usr/share/man/man5/" \
"${pkgdir}/etc/dbus-1/system.d/"
cd "${srcdir}"
install -m755 "${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
cd "${pkgname}-${pkgver}"
install -m644 "data/${pkgname}.sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -m644 "data/${pkgname}.tmpfiles.conf" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
install -m644 "data/org.asamk.Signal.conf" "${pkgdir}/etc/dbus-1/system.d/"
install -m644 "data/${pkgname}@.service" "${pkgdir}/usr/lib/systemd/system/"
install -m644 "data/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/"
install -m644 "data/${pkgname}-socket.service" "${pkgdir}/usr/lib/systemd/system/"
install -m644 "data/${pkgname}-socket.socket" "${pkgdir}/usr/lib/systemd/system/"
sed -i "s|%dir%|/usr|" "${pkgdir}/usr/lib/systemd/system/${pkgname}@.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}-socket.service"
install -m644 "man/${pkgname}.1" "${pkgdir}/usr/share/man/man1/"
install -m644 "man/${pkgname}-dbus.5" "${pkgdir}/usr/share/man/man5/"
install -m644 "man/${pkgname}-jsonrpc.5" "${pkgdir}/usr/share/man/man5/"
cd "build/install/${pkgname}"
rm -f lib/commons-logging-*.jar
rm -f lib/libsignal-client-*.jar
install -m644 lib/*.jar "${pkgdir}/usr/share/java/${pkgname}/"
}
|
