blob: d15d04039d8ae95637674500939c79c2eb8fa49d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgname=gdk-pixbuf2
pkgver=2.38.0
pkgrel=1
pkgdesc="An image loading library"
arch=(x86_64)
url="https://wiki.gnome.org/Projects/GdkPixbuf"
license=(LGPL2.1)
depends=(glib2 libpng libtiff libjpeg libx11 jasper shared-mime-info)
makedepends=(gtk-doc gobject-introspection git docbook-xsl meson)
install=gdk-pixbuf2.install
_commit=0b1eab312e77701c20b07fb8e38119009f8b34c3 # tags/2.38.0^0
source=("git+https://gitlab.gnome.org/GNOME/gdk-pixbuf.git#commit=$_commit"
gdk-pixbuf-query-loaders.hook)
sha256sums=('SKIP'
'963afcfacde9fd36031d93c8aa4c94a669ab1dbe9ba0d2cf17599b7d358e54c2')
pkgver() {
cd gdk-pixbuf
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd gdk-pixbuf
}
build() {
arch-meson gdk-pixbuf build \
-D jasper=true \
-D docs=true \
-D installed_tests=false
ninja -C build
}
check() {
cd build
# pixbuf-randomly-modified fails randomly
meson test -t 3 || :
}
package() {
DESTDIR="$pkgdir" meson install -C build
install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
}
# vim:set ts=2 sw=2 et:
|
